PlutoSDRのRESET プログラム

サンプルプログラムやいくつかのＷＥＢを参照して、PlutoSDRのRESET プログラムを作成した。プログラムの構成はシンプルに、

　・デバイスをＯＰＥＮ

　・ＰｌｕｔｏＳＤＲの電源回路の「切」コマンドの送信

　・ＰｌｕｔｏＳＤＲの電源回路の「入」コマンドの送信

　・デバイスのクローズ

となる。

ＦＴ２３２Ｒ はＵＳＢシリアルとしてそれなりに使われているので、他のデバイスを間違って操作しないように Ｐｒｏｄｕｃｔｉｏｎ Ｄｅｓｃｒｉｐｔｉｏｎ でＯＰＥＮするように。

ＦＴ Ｐｒｏｇ ユーティリティを使って Ｐｒｏｄｕｃｔｉｏｎ Ｄｅｓｃｒｉｐｔｉｏｎ を変更、初期値の「FT232R USB UART」から「FT232R PlutoCont」に変更。

デバイスマネージャーで見たとき ＣＯＭ１６、ＣＯＭ２３ は、同じＦＴ２３２ＲＬモジュールを接続しているのだが、複数挿していても明示的にOPENできて、コントロールすることができる。

ソフトは一回の操作だけなので、コンソールモードで作成、こんなふうに動作する。

エラー処理も実装したので、ＦＴ２３２ＲＬ ＵＳＢシリアルを挿していないときや別のデバイスのときなどには、

となるようにした。

これで、リモートデスクトップで操作しているときでも、ＰｌｕｔｏＳＤＲをリセットできるようになった。

参考までにＶＢ２００８ のリストを掲載。

参照設定で　ＦＴＤ２ＸＸ＿ＮＥＴ．ｄｌｌ が必要となります。

-------------------------

Imports FTD2XX_NET
Module Module1

    Sub Main()

        'ハード関係の宣言
        Dim PlutoFTDI As New FTDI
        Dim ft_status As FTD2XX_NET.FTDI.FT_STATUS
        Dim ftdiDeviceCount As UInt32 = 0

        '書き込みバッファとかその他変数
        Dim write_byte(1) As Byte
        Dim written_byte_num As UInt32 = 0
        Dim PowerON As Byte = &H0        'リレー OFF
        Dim PowerOFF As Byte = &HFF        'リレー ON

        'FTDI FT245初期化
        ft_status = FTDI.FT_STATUS.FT_OK

        'Device名をFT232R PlutoCont  EEPROMを変更しておく
        ft_status = PlutoFTDI.OpenByDescription("FT232R PlutoCont")
        If ft_status <> FTDI.FT_STATUS.FT_OK Then
            Console.WriteLine("デバイスが見つかりません")
            Console.WriteLine("接続を確認してください")
            System.Threading.Thread.Sleep(8000)
            Exit Sub
        End If

        'リセットやパージ処理
        ft_status = PlutoFTDI.ResetDevice()
        If ft_status <> FTD2XX_NET.FTDI.FT_STATUS.FT_OK Then
            Console.WriteLine("デバイスのリセットに失敗しました")
            Console.WriteLine("接続を確認してください")
            System.Threading.Thread.Sleep(8000)
            Exit Sub
        End If

        ft_status = PlutoFTDI.Purge(FTDI.FT_PURGE.FT_PURGE_RX Or FTDI.FT_PURGE.FT_PURGE_TX)
        If ft_status <> FTD2XX_NET.FTDI.FT_STATUS.FT_OK Then
            Console.WriteLine("デバイスの Purge に失敗しました")
            Console.WriteLine("接続を確認してください")
            System.Threading.Thread.Sleep(8000)
            Exit Sub
        End If


        '通信設定
        PlutoFTDI.SetTimeouts(0, 0)
        PlutoFTDI.SetLatency(100)
        PlutoFTDI.SetBaudRate(115200)

        'Bit Bang OutPutモードで起動
        ft_status = PlutoFTDI.SetBitMode(&HFF, 1)
        If ft_status <> FTD2XX_NET.FTDI.FT_STATUS.FT_OK Then
            Console.WriteLine("Bit Bang OutPutモードに失敗しました")
            Console.WriteLine("接続を確認してください")
            System.Threading.Thread.Sleep(8000)
            Exit Sub
        End If

        'Power OFF/ON Command Send

        Console.WriteLine("PlutoSDR をリセットします")

        write_byte(0) = PowerON
        ft_status = PlutoFTDI.Write(write_byte, 1, written_byte_num)
        System.Threading.Thread.Sleep(1000)

        write_byte(0) = PowerOFF
        ft_status = PlutoFTDI.Write(write_byte, 1, written_byte_num)
        System.Threading.Thread.Sleep(3000)     '３秒間電源OFFにする

        write_byte(0) = PowerON
        ft_status = PlutoFTDI.Write(write_byte, 1, written_byte_num)
        System.Threading.Thread.Sleep(1000)

        '接続をクローズしてプログラム終了
        ft_status = PlutoFTDI.ResetDevice()
        ft_status = PlutoFTDI.Close()
        Console.WriteLine("プログラムを終了します")
        System.Threading.Thread.Sleep(8000)

    End Sub

End Module